Crear un archivo autoextraible con Delphi

program SimpleSFX;
 
uses
  Windows,
  SysUtils,
  Classes,
  ZLib;
 
const
  strUID = '{EE6068A1-487C-4ED0-9DCA-9DCB0E6B35CB}';
 
// Esta funcion comprueba si existe un recurso con el nombre strUID
function CheckRes: Boolean;
var
  hRes: HRSRC;
begin
  Result:= FALSE;
  hRes:= FindResource(0, strUID, RT_RCDATA);
  if hRes <> 0 then
    Result:= TRUE;
end;
 
// Crea una copia del ejecutable con el archivo incrustado
procedure CrearSFX;
var
  Src: TFileStream;
  Temp: TMemoryStream;
  Path: String;
  hUpdateRes: THANDLE;
begin
  // Abrimos el fichero de origen como "solo lectura"
  Src:= TFileStream.Create(ParamStr(1),fmOpenRead);
  try
    Temp:= TMemoryStream.Create;
    try
      // Comprimimos el fichero
      with TCompressionStream.Create(clMax,Temp) do
      try
        CopyFrom(Src,0);
      finally
        Free;
      end;
      // La ruta del nuevo fichero es la misma que el fichero de origen + .exe
      Path:= ParamStr(1)+'.exe';
      if CopyFile(PChar(ParamStr(0)),PChar(Path),FALSE) then
      begin
        hUpdateRes:= BeginUpdateResource(PChar(Path), FALSE);
        if hUpdateRes <> 0 then
          if UpdateResource(hUpdateRes, RT_RCDATA,strUID,0,Temp.Memory,Temp.Size) then
            // Guardamos el fichero como un recurso
            if EndUpdateResource(hUpdateRes,FALSE) then
              Exit;
        DeleteFile(Path);
      end;
    finally
      Temp.Free;
    end;
  finally
    Src.Free;
  end;
end;
 
const
  BUFFERSIZE = 1024*1024;
 
procedure Extraer;
var
  Src: TResourceStream;
  Dst: TFileStream;
  Path: String;
  Buffer: PByte;
  i: Integer;
begin
  // Abrimos el recurso donde esta guardado el fichero
  Src:= TResourceStream.Create(0,strUID,RT_RCDATA);
  try
    // El fichero se extrae en la mima ruta que el ejecutable - .exe
    Path:= ChangeFileExt(ParamStr(0),EmptyStr);
    if Path <> ParamStr(0) then
    begin
      Dst:= TFileStream.Create(Path,fmCreate);
      try
        // Descomprimimos el fichero
        with TDeCompressionStream.Create(Src) do
        try
          GetMem(Buffer,BUFFERSIZE);
          try
            i:= Read(Buffer^,BUFFERSIZE);
            while i > 0  do
            begin
              Dst.Write(Buffer^,i);
              i:= Read(Buffer^,BUFFERSIZE);
            end;
          finally
            FreeMem(Buffer);
          end;
        finally
          Free;
        end;
      finally
        Dst.Free;
      end;
    end;
  finally
    Src.Free;
  end;
end;
 
 
begin
  // Comprobamos si tenemos algun archivo incrustado
  if CheckRes then
  begin
    // Si lo tenemos lo extraemos
    Extraer;
  end else
    // Si no lo tenemos y nos pasan uno como parametro, lo incrustamos
    if ParamCount = 1 then
      CrearSFX;
end.