Cifrar/descifrar usando SHA256

program Crypt;
 
{$APPTYPE CONSOLE}
 
uses
  Windows,
  SysUtils,
  Classes,
  SeSHA256 in 'SeSHA256.pas';
 
procedure Cifrar(Src, Dst: TStream; Key: WideString; Desc: Boolean);
var
  i,j: Integer;
  Temp: TMemoryStream;
  Buffer, Hash: TSHA256HASH;
begin
  Temp:= TMemoryStream.Create;
  try
    // Leemos el primer bloque (32 bytes)
    i:= Src.Read(Buffer,Sizeof(Buffer));
    while i > 0 do
    begin
      // Añadimos la clave al buffer anterior para generar el Hash
      Temp.WriteBuffer(PWideChar(Key)^,Length(Key)*Sizeof(WideChar));
      Temp.Position:= 0;
      // Generamos el hash de la clave y el buffer anterior
      Hash:= CalcSHA256(Temp);
      Temp.Clear;
      if Desc then
        // Si estamos descifrando usamos el buffer antes de descifrar
        Temp.WriteBuffer(Buffer,Sizeof(Buffer));
      for j:= 0 to 7 do
        // Ciframos el buffer con el hash generado
        Buffer[j]:= Buffer[j] xor Hash[j];
      // Escribimos el resultado
      Dst.WriteBuffer(Buffer,i);
      if not Desc then
        // Si estamos cifrando usamos el buffer despues de cifrar
        Temp.WriteBuffer(Buffer,Sizeof(Buffer));
      // Leemos el siguiente bloque  
      i:= Src.Read(Buffer,Sizeof(Buffer));
    end;
  finally
    Temp.Free;
  end;
end;
 
var
  Origen, Destino: TFileStream;
begin
  if ParamCount < 3 then
    Exit;
  try
    Origen:= TFileStream.Create(ParamStr(1),fmOpenRead or fmShareDenyWrite);
    try
      Destino:= TFileStream.Create(ParamStr(2),fmCreate);
      try
        // Ciframos o desciframos dependiendo del parametro /d
        Cifrar(Origen,Destino,ParamStr(3),FindCmdLineSwitch('d',TRUE));
      finally
        Destino.Free;
      end;
    finally
      Origen.Free;
    end;
  except
    On E: Exception do
      Writeln(E.Message);
  end;
end.

Crypt origen.txt cifrado.bin Clave
Crypt cifrado.bin descifrado.txt Clave /d